home *** CD-ROM | disk | FTP | other *** search
/ Complete Linux / Complete Linux.iso / docs / apps / circuits / spice2g6.z / spice2g6 / spice / small.inp < prev    next >
Encoding:
Text File  |  1993-05-19  |  1.5 KB  |  42 lines
  1. *  CMOS Ring oscillator (7 inverters)
  2. *
  3. .width out=80
  4. *  Transistors :
  5. mq1n   2     1     0     0     CMOSN l=3u w=4.5u
  6. mq1p   2     1   100   100     CMOSP l=3u w=4.5u
  7. mq2n   3     2     0     0     CMOSN l=3u w=4.5u
  8. mq2p   3     2   100   100     CMOSP l=3u w=4.5u
  9. mq3n   4     3     0     0     CMOSN l=3u w=4.5u
  10. mq3p   4     3   100   100     CMOSP l=3u w=4.5u
  11. mq4n   5     4     0     0     CMOSN l=3u w=4.5u
  12. mq4p   5     4   100   100     CMOSP l=3u w=4.5u
  13. mq5n   6     5     0     0     CMOSN l=3u w=4.5u
  14. mq5p   6     5   100   100     CMOSP l=3u w=4.5u
  15. mq6n   7     6     0     0     CMOSN l=3u w=4.5u
  16. mq6p   7     6   100   100     CMOSP l=3u w=4.5u
  17. mq7n   1     7     0     0     CMOSN l=3u w=4.5u
  18. mq7p   1     7   100   100     CMOSP l=3u w=4.5u
  19. *
  20. *  Voltage cards :
  21. vdd 100     0     dc     5V
  22. *
  23. *  Analysis cards :
  24. .tran 100ps 1ns
  25. .plot tran v(1) v(7)
  26. .ic v(1)=0 v(3)=0 v(5)=0 v(7)=0
  27. *
  28. *  Model cards :
  29. .MODEL CMOSN NMOS (VTO=0.83 KP=33U GAMMA=1.36 PHI=0.6
  30. + LAMBDA=0.016 PB=0.8 JS=10N LD=0.28U TOX=50N NSUB=1E16
  31. + UO=200 UEXP=0.1 UCRIT=4E4 VMAX=100K XJ=0.4U
  32. + DELTA=1.24 NFS=0 NEFF=2 NSS=0 TPG=1.0 RSH=25
  33. + CGSO=0.5N CGDO=0.5N CJ=0.32M MJ=0.5 CJSW=0.9N MJSW=0.33
  34. + CGBO=0 FC=0.5 LEVEL=2)
  35. .MODEL CMOSP PMOS (VTO=-0.89 KP=15U GAMMA=0.88 PHI=0.6
  36. + LAMBDA=0.047 PB=0.8 JS=10N LD=0.28U TOX=50N NSUB=1.12E14
  37. + UO=100 UEXP=0.1 UCRIT=20E4 VMAX=100K XJ=0.4U
  38. + DELTA=1.94 NFS=0 NEFF=2 NSS=0 TPG=-1.0 RSH=95
  39. + CGSO=0.4N CGDO=0.4N CJ=0.2M MJ=0.5 CJSW=0.45N MJSW=0.33
  40. + CGBO=0 FC=0.5 LEVEL=2)
  41. .end
  42.